/* Compare t-test results to dummy regression results  */
reg realrinc white if year==2006

reg realrinc white educ if year==2006
predict yhat1

/* add in interaction term */
reg realrinc white educ race_ed if year==2006
predict yhat2


/* Create graphical representation */

/* Dichotomous variable */
#delimit ;
graph twoway (lfit realrinc white if year==2006) 
             (scatter realrinc white if year==2006, jitter(7)),
  title("Dummy Variable")
  xtitle("")
  ytitle("Income")
  xlabel(0 "Black" 1 "White")
  ylabel(25000 "25K" 50000 "50K" 75000 "75K" 100000 "100K")
  name(g1, replace)
  nodraw
;
#delimit cr


/* Dichotomous and continuous variables */
#delimit ;
graph twoway (scatter yhat1 educ if white==0 & year==2006 & yhat1>=0, ms(i) c(l)) 
             (scatter yhat1 educ if white==1 & year==2006 & yhat1>=0, ms(i) c(l)), 
  title("Dummy and Continuous Variable")
  xtitle("Education")
  ytitle("Income")
  xtick(5(1)20)
  ylabel(10000 "10K"  20000 "20K"  30000 "30K"  40000 "40K" 50000 "50K")
  ytick(0(5000)50000)
  legend(on cols(1) ring(0) pos(5) label(1 "Black") label(2 "White"))
  name(g2, replace)
  nodraw
;
#delimit cr


/* Dichotomous and continuous variables with interaction*/
#delimit ;
graph twoway (scatter yhat2 educ if white==0 & year==2006 & yhat2>=0, ms(i) c(l)) 
             (scatter yhat2 educ if white==1 & year==2006 & yhat2>=0, ms(i) c(l)), 
  title("Dummy and Continuous Variable with Interaction")
  xtitle("Education")
  ytitle("Income")
  xtick(5(1)20)
  ylabel(10000 "10K"  20000 "20K"  30000 "30K"  40000 "40K" 50000 "50K")
  ytick(0(5000)50000)
  legend(on cols(1) ring(0) pos(5) label(1 "Black") label(2 "White"))
  name(g3, replace)
  nodraw
;
#delimit cr

/* Put all the graphs into one */
graph combine g1 g2 g3, nocopies

/* Clean up */
drop yhat1 yhat2