/*
   The user written program estout produces formatted
     regression output to an external file in a number 
     of formats or alternatively to the Stata results 
     window. I show several examples below.

   Enter "findit estout" to find this program and
     install it in the usual way.
*/


/* Define local macros with groups of independent variables */
local wrk_status "fulltime-school"
local occup "tech serv farm oper"
local demog "men white age childs"
local geog  "mw-w size"
local jobatrb "jobinc1 jobmeans1"


/*
   The following regression examples uses the Stata command 
     nestreg to calculate extra sums of squares tests.  nestreg 
     fits nested models by sequentially adding blocks of variables 
     and then reports comparison tests between the nested models.
*/

estimates clear
quietly reg realrinc `wrk_status' if year==2006
estimates store m1, title("Model 1")

quietly reg realrinc `wrk_status' `occup' if year==2006
estimates store m2, title("Model 2")

quietly reg realrinc `wrk_status' `occup' educ race_ed if year==2006
estimates store m3, title("Model 3")

estout m1 m2 m3
estout m1 m2 m3 using bigmodel1.txt, replace
estout m1 m2 m3 using bigmodel2.txt, replace style(fixed)
estout m1 m2 m3 using bigmodel3.txt, replace style(fixed) cells(b se)
estout       m3 using bigmodel4.txt, replace style(fixed) cells("b se t p")
estout       m3 using bigmodel5.txt, replace style(fixed) cells("b p" se)
estout m1 m2 m3 using bigmodel6.txt, replace style(fixed) cells(b(star fmt(2)) t(par fmt(2)))
estout m1 m2 m3 using bigmodel7.txt, replace style(fixed) cells(b(star fmt(2)) t(par fmt(2))) stats(r2 N)

#delimit ;
estout m1 m2 m3 using bigmodel8.txt, 
  replace 
  style(fixed) 
  noabbrev
  varwidth(17)
  varlabels(fulltime "Fulltime"
            parttime "Parttime"
            not_work "Not Working"
            unempl   "Unemployed"
            retired  "Retired"
            school   "In school"
            tech     "Tech/Sales"
            serv     "Service"
            farm     "Farmers/Fisherman"
            oper     "Operatives"
            _cons   "Constant"
            race_ed "RaceXEducation"
            educ    "Education")
;
#delimit cr