/*
   Post-hoc Statistical Control

   The coefficient b1 measures the effect of X1 on Y, with the effect
     of X2 controlled or held statistically constant. Simultaneously,
     The coefficient b2 measures the effect of X2 on Y, with the effect
     of X1 controlled or held statistically constant.

   We can understand this by realizing the estimated coefficients in the
     three variable regression model can be calculated by solving two,
     two-variable regressions.

   The first regression adjusts the variable X1 to hold X2 constant. The
     second regression estimates the effect of this adjusted variable on Y.

   Regress X1 on X2.
   When this model has been estimated, we can calculate the fitted and
     residual values. The fitted values encompass the correlation between X1
     and X2; the residuals contain information on the uncorrelated portion
     of the relationship between the two independent measures.

   Regress Y on the residuals of the above model.
   The resulting coefficient will be equal to b1. We can interpret statistical
     control in this case as eliminating the effect of X2 from X1 and examining
     the "pure" relationship between Y and X1.  Holding X2 constant means
     eliminating from X1 that component that is correlated with X2.

   Regress X2 on X1.
   The fitted values encompass that correlation between X2 and X1. The fitted
     values encompass that correlation between X2 and X1; the residuals contain
     information on the uncorrelated portion of the relationship between the
     two independent measures.

   Regress Y on the residuals of the above model.
   The resulting coefficient will be equal to b2
*/


/* Chapter 8, Table 8.1, p. 115 */
capture clear
input byte wgt byte hgt byte age
64      57      8
71      59     10
53      49      6
67      62     11
55      51      8
58      50      7
77      55     10
57      48      9
56      42     10
51      42      6
76      61     12
68      57      9
end

gen int age2=age^2

label variable wgt  "Weight (Y)"
label variable hgt  "Height (X1)"
label variable age  "Age (X2)"
label variable age2 "Age-squared (X3)"


/* Look at all bivariate relationships */
graph matrix wgt hgt age age2, name(bivariate, replace)

/* Demonstrate principles of post-hoc statistical control */
corr wgt hgt age                /* Look at bivariate correlations */

reg hgt age                     /* Regress X1 on X2                        */
tempvar hgt_age                 /* Create temporary variable for residuals */
predict `hgt_age', residuals    /* Create the residuals                    */
format `hgt_age' %7.4f          /* Format the residuals to look nice       */

reg age hgt                     /* Regress X1 on X2                        */
tempvar age_hgt                 /* Create temporary variable for residuals */
predict `age_hgt', residuals    /* Create the residuals                    */
format `age_hgt' %7.4f          /* Format the residuals to look nice       */

reg wgt hgt age                 /* Estimate the multiple regression        */
reg wgt `hgt_age'               /* Estimate the Y regressed on resid1 (b1) */
reg wgt `age_hgt'               /* Estimate the Y regressed on resid2 (b2) */