log using "SOCY602-GSS-Sociability-ttest-Example.txt", replace text

/* Work problem similar to the one on p. 20 */
ci sociability if year==2006
ci sociability if year==2006, level(99)

/* Statistically compare means across gender */
ttest sociability if year==2006, by(sex)

/* Check the power of this test */
sampsi 10.5023 10.05451, n1(868) n2(1119) sd1(4.45288) sd2(3.946384) 
sampsi 10.5023 10.05451, n1(868) n2(1119) sd1(4.45288) sd2(3.946384) onesided


/* Use returned values (see help return) */
ttest sociability if year==2006, by(sex)
sampsi `r(mu_1)' `r(mu_2)', n1(`r(N_1)') n2(`r(N_2)') sd1(`r(sd_1)') sd2(`r(sd_2)') 


/* Determining sample size */
sampsi 10.4 11.2883, sd(4.26)
sampsi 10.4 12.5666, sd(4.26)
sampsi 10.4 13.8450, sd(4.26) 


/* 
   Determining sample size 
   According to Cohen standardized differences of 0.2, .05, and 
     0.8 are respectively small, medium, and large.  The standardized
     difference is simply a z-score.  In this example we can determine
     the mean of the other group with an effect size of 0.2 by
     solving the following problem:

          mean2=(effect)(sd)+mean, or mean2=(0.2)(4.26)+ 10.4

    We can automate the whole process by writing a small program that
      uses loops, returned values, and local macros.  See if you can 
      figure out the following code!
*/
quietly {
  sum sociability
  foreach num of numlist .2 .5 .8 {
    sum sociability
    local power=(`num'*`r(sd)')+`r(mean)'
    noisily sampsi `r(mean)' `power', sd(`r(sd)') 
  }
}

log close