/*
   Create sociability scale variable.

   SOCIABILITY
     socrel   - spend evening with relatives
     socommun - spend evening with neighbor
     socfrend - spend evening with friends
     socbar   - spend evening at bar
*/
log using "SOCY602-GSS-Sociability-Scale.txt", replace text

/* Check out the sociability measures */
local check "socrel socommun socfrend socbar"
foreach var of varlist `check' {
  tab `var'
}
tabstat `check', by(year)


/*
   Reverse code the sociability measures.  The following uses a user-written
     program called "vreverse".  Type findit "vreverse" at the command line
     to install the program.
*/
foreach var of varlist `check' {
  vreverse `var', gen(`var'1)
}


/* For completeness check out the new variables */
local check "socrel1 socommun1 socfrend1 socbar1"
foreach var of varlist `check' {
  tab `var'
}


/* Create sociability additive scale */
gen sociability=socrel1+socommun1+socfrend1+socbar1-4
label variable sociability "Sociability Scale (0-24)"
tab sociability
tabstat sociability, by(year)


/* Clean up the dataset */
drop socrel1 socommun1 socfrend1 socbar1    /* Get rid of temporary variables                    */
compress                                    /* Make certain all variables are efficiently stored */

log close