quietly {
  /*
     Here we put a lot of information together.  This plot
       shows the studentized residuals plotted against the
       hat values (leverage) with each point weighted by
       Cook's D.

     As before, no values exceed the leverage cutoff value,
       but, two cases affect the jacknifed residuals and
       seem influential looking at ALL the fitted values.
  */
     
  regress  y  x 
  predict  y_stud, rstudent
  predict  y_hat , leverage
  predict  y_cook, cooksd

  regress y1  x 
  predict y1_stud, rstudent
  predict y1_hat , leverage
  predict y1_cook, cooksd

  regress y2  x 
  predict y2_stud, rstudent
  predict y2_hat  , leverage
  predict y2_cook , cooksd

  local j=1
  local n=10
  local alpha=0.05
  local tplus =invttail(`n'-1,`alpha'/2)
  local tminus=invttail(`n'-1,`alpha'/2)*-1
  local hat2=2*((`j'+1)/`n')
  local hat3=3*((`j'+1)/`n')

  #delimit ;
  graph twoway (scatter  y_stud  y_hat [aweight= y_cook]), 
    ylabel(-3(1)5)                                         
    xlabel(0(.05).4)                                       
    title("Original Data")                                 
    ytitle("") xtitle("")                                  
    yline(`tminus' 0 `tplus', lp(dash) lw(thick))          
    xline(`hat2' `hat3', lp(dash) lw(thick))               
    name(cooks1, replace) nodraw
  ;
  #delimit cr

  #delimit ;
  graph twoway (scatter y1_stud y1_hat [aweight=y1_cook]), 
    ylabel(-3(1)5)                                         
    xlabel(0(.05).4)                                       
    title("Scenario #1")                                   
    ytitle("") xtitle("")                                  
    yline(`tminus' 0 `tplus', lp(dash) lw(thick))          
    xline(`hat2' `hat3', lp(dash) lw(thick))               
    text(5 .1 "Obs. 5")                                    
    name(cooks2, replace) nodraw
  ;
  #delimit cr

  #delimit ;
  graph twoway (scatter y2_stud y2_hat [aweight=y2_cook]), 
    ylabel(-3(1)5)                                         
    xlabel(0(.05).4)                                       
    title("Scenario #2")                                   
    ytitle("") xtitle("")                                  
    yline(`tminus' 0 `tplus', lp(dash) lw(thick))          
    xline(`hat2'       , lp(dash) lw(thick))               
    text(2.9 .345 "Obs. 10")                               
    name(cooks3, replace) nodraw
  ;
  #delimit cr

  #delimit ;
  graph combine cooks1 cooks2 cooks3,                      
    title("Unusual and Influential Data")                  
    subtitle("Studentized Residuals Plotted Against hat values, weighted by Cook's D") 
    name(multiple, replace)
  ;
  #delimit cr

  drop y_stud- y2_cook
}