regress y  x 
predict  y_resid_sta, rstandard

regress y1 x 
predict y1_resid_sta, rstandard

regress y2 x 
predict y2_resid_sta, rstandard

label variable  y_resid_sta "Original Data"
label variable y1_resid_sta "Scenario #1"
label variable y2_resid_sta "Scenario #2"


*/ Look at Data Graphically */
stem  y_resid_sta
stem y1_resid_sta
stem y2_resid_sta


#delimit ;
graph box  y_resid_sta y1_resid_sta y2_resid_sta, asc
  title("Box Plots of Standardized Residuals")
  ytick(-2(.5)3)
  name(boxplots, replace)
;
#delimit cr


quietly {
  local alpha=0.05
  local tcritp=invttail(e(df_r),`alpha'/2)
  local tcritm=`tcritp'*-1
  noisily di _n _col(2) "{text}" "|t-critical|=" %7.3f `tcritp'
  noisily list x y   y_resid_sta if  ( y_resid_sta>`tcritp' |  y_resid_sta<`tcritm')
  noisily list x y1 y1_resid_sta if  (y1_resid_sta>`tcritp' | y1_resid_sta<`tcritm')
  noisily list x y2 y2_resid_sta if  (y2_resid_sta>`tcritp' | y2_resid_sta<`tcritm')
}


/* Density Plots */
#delimit ;
kdensity  y_resid_sta, normal title("Original Data")
  xtitle("") note("") 
  name(g1, replace) nodraw
;

kdensity y1_resid_sta, normal title("Scenario #1")
  xtitle("") note("") 
  name(g2, replace) nodraw
;

kdensity y2_resid_sta, normal title("Scenario #2")
  xtitle("") note("") 
  name(g3, replace) nodraw
;

graph combine g1 g2 g3, title("Graphical Check for Normality")
  name(kdens, replace) nocopies ycommon xcommon 
;
#delimit cr


/* Normap Probability Plots */
sort y_resid_sta
tempvar ordinate
generate `ordinate'=_n/_N

#delimit ;
graph twoway (scatter `ordinate'  y_resid_sta),
  title("Original Data")
  xtitle("")
  ytitle("")
  name(cumplot1, replace) nodraw
;

sort y1_resid_sta;
replace `ordinate'=_n/_N;

graph twoway (scatter `ordinate' y1_resid_sta),
  title("Scenario #1")
  xtitle("")
  ytitle("")
  name(cumplot2, replace) nodraw
;

sort y2_resid_sta;
replace `ordinate'=_n/_N;

graph twoway (scatter `ordinate' y2_resid_sta),
  title("Scenario #2")
  xtitle("")
  ytitle("")
  name(cumplot3, replace) nodraw
;

graph combine cumplot1 cumplot2 cumplot3,     ///
  title("Normal Probability Plot of Standardized Residuals") nocopies 
;
#delimit cr


/* PNORM Plots */
#delimit ;
pnorm  y_resid_sta,
  title("Original Data")
  ms(i) mlabel(obs) mlabposition(0)
  ytitle("")
  name(g1, replace) nodraw
;

pnorm y1_resid_sta ,
  title("Scenario #1")
  ms(i) mlabel(obs) mlabposition(0)
  ytitle("")
  name(g2, replace) nodraw
;

pnorm y2_resid_sta,
  title("Scenario #2")
  ms(i) mlabel(obs) mlabposition(0)
  ytitle("")
  name(g3, replace) nodraw
;

graph combine g1 g2 g3,
  title("PNORM Graphical Check for Normality")
  note("Sensitive to middle range of the data.")
  name(pnorm, replace) nocopies
;
#delimit cr


#delimit ;
/* QNORM Plots */
qnorm  y_resid_sta,
  title("Original Data")
  ytitle("")
  ms(i) mlabel(obs) mlabposition(0)
  name(g1, replace) nodraw
;

qnorm y1_resid_sta,
  title("Scenario #1")
  ytitle("")
  ms(i) mlabel(obs) mlabposition(0)
  name(g2, replace) nodraw
;

qnorm y2_resid_sta,
  title("Scenario #2")
  ytitle("")
  ms(i) mlabel(obs) mlabposition(0)
  name(g3, replace) nodraw
;

graph combine g1 g2 g3,
  title("QNORM Graphical Check for Normality")
  note("Sensitive to tails of the data.")
  name(qnorm, replace) nocopies
;
#delimit cr


/* 
   Statistical Tests of Normality:
     swilk performs the Shapiro-Wilk W test for normality, and sfrancia
       performs the Shapiro-Francia W' test for normality.  

     swilk can be used with 7<=n<=2000 observations, and sfrancia can be 
       used with with 5<=n<=5000 observations; see sktest for a test 
       allowing a larger number of observations.
     The null is the variable is normally distributed.
*/
swilk    y_resid_sta y1_resid_sta y2_resid_sta
sfrancia y_resid_sta y1_resid_sta y2_resid_sta
sktest   y_resid_sta y1_resid_sta y2_resid_sta

drop  y_resid_sta- y2_resid_sta