/* Create subset of the GSS data for this example */
#delimit ;
use year
    prestg80
    educ
        age
        sex
        race
        marital using "C:\data\GSS-98-08.dta" if year==2008 & race<3, clear
;
#delimit cr
drop year

/* Rename dummy variables for clarity */
rename sex female
rename race black


/*
   Estimate regression model
   Keep all cases used in estimation
   Create predicted values, Y-hats
   Create Figure 1
*/
xi: regress prestg80 educ age i.female i.black
keep if e(sample)

/* Three alternatives to creating a variable of predicted values */

/*
Method #1
gen yhat=5.707446   + ( 2.458468 *educ) +           ///
                      (  .0995691*age) +            ///
                      (  .3035981*_Ifemale_2) +     ///
                      (-1.443287 *_Iblack_2)

                                          Method #2
gen yhat=_b[_cons]  + (_b[educ]*educ) +             ///
                      (_b[age]*age) +               ///
                      (_b[_Ifemale_2]*_Ifemale_2) + ///
                                          (_b[_Iblack_2]*_Iblack_2)
*/

/* Method #3 */
predict yhat, xb


/* Compare mean Y-hat to adjust command */

/* Figure  2 */
tabstat yhat
adjust

/* Figure  3 */
table marital if !missing(marital), contents(mean  yhat) format(%6.4f)
adjust, by(marital)

/* Figure  4 */
table marital female if !missing(marital), contents(mean yhat) format(%6.4f)
adjust, by(marital female)

/* Figure  5 */
adjust, by(marital female) format(%6.2f)
adjust _Iblack_2, by(marital female) format(%6.2f)

/* Figure  6 */
adjust educ age, by(marital female) format(%6.2f)

/* Figure  7 */
adjust _Ifemale_2=0 _Iblack_2=0 , by(marital female) format(%6.2f)

/* Figure  8 */
adjust, by(marital female) format(%6.2f) ci

/* Figure  9 */
adjust if mod(age,5)==0, by(age) format(%6.2f) ci

/* Figure 10 */
adjust if mod(age,5)==0, by(age) stdf ci