capture log close
log using "SOCY699C-HW7-LOOPS.smcl", smcl replace

/* Grab a subset of the GSS */
#delimit ;
use year
    educ
    age
    sexfreq
    marital using http://terpconnect.umd.edu/~smilex3/GSS-Cumulative-72-12.dta, clear;
#delimit cr


/* Problem #1 */
capture drop leduc lage
foreach var of varlist educ age {
  gen l`var'=log(`var')
  label variable l`var' "Logged version of `var'"
}


/* Problem #2 */
/* Create the yearly sexual frequency variable */
capture drop sexfreq3
generate sexfreq3=.
replace  sexfreq3=  0 if sexfreq==0
replace  sexfreq3=  2 if sexfreq==1
replace  sexfreq3= 12 if sexfreq==2
replace  sexfreq3= 36 if sexfreq==3
replace  sexfreq3= 52 if sexfreq==4
replace  sexfreq3=156 if sexfreq==5
replace  sexfreq3=208 if sexfreq==6
label variable sexfreq3 "Yearly sexual frequency"

foreach num of numlist 1(1)5 {
  quietly regress sexfreq3 age if marital==`num' & year==2012
  di `num' " " _b[age] " " e(r2)
}

/* The table can be dressed up a bit by adding column
     headings, formatting the numbers, and spacing
     the results for readability.  See -help display-
     for more information on all the things you can do.
*/
quietly {
  noisily di _n "Marital"
  noisily di "Status" _col(12) "b" _col(19) "r2"
  foreach num of numlist 1(1)5 {
     regress sexfreq3 age if marital==`num' & year==2012
    noisily di _col(4) `num' _col(9) %6.3f _b[age] _col(18) %4.2f e(r2)
  }
}

log close