capture log close
log using "Gotchas\SOCY699C-HW5-GOTCHAS-MISSING.smcl", smcl replace
/* Gotchas */

/* Understanding missing values */
clear
input str1 id byte y
"a"  1
"b"  2
"c"  3
"d"  .
""   5
end
list, noobs
list y if y>=5, noobs
list y if y>=5 & y <., noobs


gen byte y1=(y>=3)        /* Missing values are set equal to 1 */
gen byte y2=(y>=3 & y<.)  /* Missing values are set equal to 0 */
generate y3=.
replace y3=0 if y<3
replace y3=1 if y>=3 & y<.
generate byte y4=cond(y<3,0,cond(y>=3 & y<.,1,.))
list, noobs

gen y5=y
replace y5=.a if y==5
list y5, noobs
list y5 if !missing(y5), noobs
list y5 if y5<=., noobs

list id if  missing(id)
list id if !missing(id)


/* Problems */
local gss "http://terpconnect.umd.edu/~smilex3/GSS-Cumulative-72-12.dta"
#delimit ;
use year
    socbar
    socrel
    socommun
    socfrend using "`gss'", clear;
#delimit cr

replace socrel   =.a if socrel   >=.
replace socommun =.b if socommun >=.
replace socfrend =.c if socfrend >=.
replace socbar   =.d if socbar   >=.

list socrel socommun socfrend socbar in 23414/23425


foreach var of varlist socrel socommun socfrend socbar {
  recode `var' (min/7=0) (else=1), gen(`var'1)
}

egen socmiss=rowtotal(socrel1-socbar1)
tab socmiss
tab socmiss if socmiss >0

drop socrel1 socommun1 socfrend1 socbar1 socmiss

log close